Le grenier Access

Copier un chemin Windows rapidement

Hervé Inisan — Tue, 24 Aug 2010 09:35:00 +0200

Le saviez-vous ?

On a souvent besoin du chemin d'un dossier ou d'un fichier, par exemple pour le récupérer dans du code VBA.
Plutôt que de retaper manuellement ce chemin, vous pouvez l'obtenir grâce à Windows (Vista ou 7).

Méthode #1

La première méthode est directe :

Cliquez sur l'icône à gauche des noms de dossiers, dans la barre d'adresse d'une fenêtre Windows.
La liste de dossiers se transforme en chemin (présélectionné en bleu, d'ailleurs).
Faites un CTRL + C (ou un clic droit / Coller).
Vous pouvez maintenant coller ce chemin dans un module VBA, ou n'importe où d'autre !

L'inconvénient, par contre, est que seuls les chemins de dossiers peuvent être récupérés de cette manière, pas ceux des fichiers.

Méthode #2

Très pratique aussi :

Cliquez du bouton droit sur un fichier ou un dossier, tout en restant appuyer sur la touche [Majuscule] (Shift, pour ceux qui sont toujours bloqués sur des claviers anglais ;-)).
Dans le menu apparaît alors une commande Copier en tant que chemin d'accès.
Vous n'avez plus qu'à coller le résultat quelque part...

Extraire les pièces jointes d'Outlook en VBA

Hervé Inisan — Mon, 23 Aug 2010 11:03:00 +0200

Dans Outlook (pas Express), j'ai des e-mails avec pièces jointes. Comment extraire toutes ces pièces jointes automatiquement, en VBA, dans un dossier du disque dur ?

Mise en place

Le code qui va suivre utilise lui-même d'autres portions de VBA publiées sur ce blog, portions que vous devez aussi intégrer à votre base de données. Reportez-vous à ces articles :

D'autre part, votre projet VBA doit référencer la bibliothèque "Microsoft Outlook x.y Object Library" (x.y étant votre version d'Outlook, par exemple 12.0). Pour plus de détails sur les références, consultez cet article du blog.

Le code

Voici 2 procédures VBA à recopier intégralement dans un module standard de votre base de données.

' ---

' EXTRACTION DE PIECES JOINTES OUTLOOK

' ---

'

Sub SaveAttachments( _

  ByVal strTargetFolder As String, _

  Optional ByVal blnIncludeSubFolders As Boolean = False)

  ' Quelques variables...

  Dim olApp As Outlook.Application

  Dim ns As Outlook.NameSpace

  Dim fld As Outlook.MAPIFolder

  ' Vérifier si le dossier de destination existe bien

  If Dir(strTargetFolder, vbDirectory) = "" Then

    MsgBox "Le dossier destination n'existe pas !", vbExclamation

    Exit Sub

  End If

  strTargetFolder = AddBackslash(strTargetFolder)

  ' Démarrer Outlook

  Set olApp = New Outlook.Application

  ' Pointer sur la boîte de réception

  Set ns = olApp.GetNamespace("MAPI")

  Set fld = ns.GetDefaultFolder(olFolderInbox)

  ' Extraire tous les messages du dossier

  SaveFolderAttachments fld, strTargetFolder, blnIncludeSubFolders

  Set fld = Nothing

  Set ns = Nothing

  olApp.Quit

  Set olApp = Nothing

End Sub

' ---

' EXTRACTION DES PIECES JOINTES D'UN DOSSIER

' ---

'

Sub SaveFolderAttachments( _

  fld As Outlook.MAPIFolder, _

  strTargetFolder As String, _

  Optional ByVal blnIncludeSubFolders As Boolean = False)

  Dim mi As Outlook.MailItem

  Dim att As Outlook.Attachment

  Dim strFile As String

  ' Debug

  Debug.Print "---"

  Debug.Print "DOSSIER : " & fld.Name

  Debug.Print "---"

  ' Parcourir tous les messages

  For Each mi In fld.Items

    If mi.Attachments.Count > 0 Then

      ' Pour info...

      Debug.Print mi.Subject

      For Each att In mi.Attachments

        strFile = FilenameInc(strTargetFolder & att.Filename)

        ' Sauvegarder la pièce jointe sous son nom original

        ' ou avec un nom incrémenté en cas de doublons

        att.SaveAsFile strFile

        Debug.Print "  -> " & strFile

      Next

    End If

  Next

  ' Si nécessaire, effectuer le même traitement

  ' sur les sous-dossiers

  If blnIncludeSubFolders Then

    Dim subfld As Outlook.MAPIFolder

    For Each subfld In fld.Folders

      SaveFolderAttachments subfld, strTargetFolder, blnIncludeSubFolders

    Next

  End If

End Sub

Tester le code

En principe, vous appelez la 1ère des deux procédures de cette manière :

Ouvrez la fenêtre Exécution (CTRL + G).
Tapez :
SaveAttachments "C:\un\dossier\existant\quelconque"
puis [Entrée].

Toutes les pièces jointes de messages situés dans la boîte de réception seront alors extraites dans le dossier souhaité (s'il existe, bien sûr).

Notes

Si deux messages (ou plus) contiennent une pièce jointe de même nom, ces pièces jointes seront toutes sauvées et numérotées différemment. Par exemple : photo.jpg, photo-00001.jpg, photo-00002.jpg, etc. C'est la fonction FilenameInc() traitée dans cet article qui prend en charge la numérotation.
La fenêtre Exécution affiche quelques informations utiles (sujet du message, chemin de la pièce jointe sauvegardée).

Variante

Si votre boîte de réception contient des sous-dossiers, ceux-ci ne sont pas traités par défaut. Si vous souhaitez que tous les sous-dossiers de votre boîte de réception soient parcourus, écrivez plutôt :
SaveAttachments "C:\un\dossier\existant\quelconque", True
Le second paramètre indique qu'il faut parcourir les sous-dossiers de façon récursive.

Générer un nom de fichier avec numéro

Hervé Inisan — Sun, 22 Aug 2010 14:49:00 +0200

Ok, le titre de ce billet est complètement nébuleux ! En clair : vous disposez du chemin complet d'un fichier (par exemple : C:\un\chemin\quelconque\test.jpg), et vous souhaitez le transformer en C:\un\chemin\quelconque\test-00001.jpg si un fichier test.jpg existe déjà à cet emplacement.

Quelques pré-requis

Le code qui va suivre utilise lui-même d'autres portions de VBA publiées sur ce blog, portions que vous devez aussi intégrer à votre base de données. Reportez-vous à ces articles :

Le code

' ---

' INCREMENTATION BASIQUE D'UN NOM DE FICHIER

' ---

' Entrée : Chemin complet

'          Ex. : C:\un\chemin\quelconque\test.jpg

' Sortie : Chemin incrémenté, si un fichier existe déjà à cet emplacement.

'          Ex. : C:\un\chemin\quelconque\test-00001.jpg

Function FilenameInc(ByVal strFile As String) As String

  Dim strFileTemp As String

  Dim intI As Integer

  ' Si le fichier n'existe pas, on conserve son

  ' nom d'origine

  If Dir(strFile) = "" Then

    FilenameInc = strFile

    Exit Function

  End If

  ' Créer un nouveau nom de fichier numéroté,

  ' en vérifiant qu'il n'existe pas déjà

  intI = 1

  strFileTemp = strFile

  While Dir(strFileTemp) <> ""

    strFileTemp = StringFormat("{0}{1}-{2}.{3}", _

      FilePath(strFile), _

      FilenameWithoutExt(strFile), _

      Format(intI, "00000"), _

      FileExt(strFile))

    intI = intI + 1

  Wend

  ' Valeur de retour

  FilenameInc = strFileTemp

End Function

Exemple

Pour tester ce bout de code :

Ouvrez la fenêtre Exécution (CTRL + G).
Tapez-y quelque chose comme :
? FilenameInc("C:\un\chemin\quelconque\test.jpg")

Si aucun fichier test.jpg, n'existe à cet emplacement, le résultat affiché sera :
C:\un\chemin\quelconque\test.jpg

Dans le cas contraire, le chemin sera :
C:\un\chemin\quelconque\test-00001.jpg

Et si un fichier test-00001.jpg existe aussi, le chemin proposé sera :
C:\un\chemin\quelconque\test-00002.jpg

Bien sûr, ce code n'a aucun intérêt s'il est utilisé tout seul. La fonction FilenameInc() ne renomme pas de fichier, elle ne fait que proposer le prochain "nom numéroté" disponible. Elle sera utilisée dans d'autres articles à venir.

Redimensionner les formulaires automatiquement à l'aide de ShrinkerStretcher

Hervé Inisan — Fri, 16 Jul 2010 19:05:00 +0200

Access ne redimensionne pas les formulaires en fonction de la résolution écran.

Du coup, quand vous construisez vos formulaires, il est conseillé de définir votre taille écran en fonction de l'utilisateur final. Concrètement, si un utilisateur est en 1024x768 alors que tout le monde travaille en 1900x1200, vous construirez vos formulaires en abaissant votre propre résolution à 1024x768... Sinon, le "redesign" des formulaires peut vous demander pas mal de temps...

Mais dans certaines situations, vous souhaiterez peut-être un redimensionnement automatique. C'est ici qu'intervient ShrinkerStretcher... (jetez un oeil au screencast en bas d'article, pour voir le résultat)

Télécharger ShrinkerStretcher

ShrinkerStretcher est donc une bibliothèque qui se charge de redimensionner vos formulaires "à la volée". Cet outil peut être téléchargé sur le site de Peter's Software.
Vous trouverez, à cette adresse des liens pour télécharger des versions d'évaluation, et en bas de la page, des liens pour acheter des licences (1 licence par application et par poste installé, quand même !).

Info

La version de démonstration affiche de temps en temps des "nag screens" (des boîtes de dialogue qui vous rappellent d'acheter la licence).

Installer ShrinkerStretcher

Cet article utilise la version de démonstration, qui est fournie dans un fichier Zip :

Commencez par extraire tout le contenu du fichier Zip (clic du bouton droit sur le fichier ss.zip, puis Extraire tout).
Dans le dossier obtenu, double-cliquez sur Setup.exe, ce qui lance l'installation (en fait d'installation, il s'agit surtout de décompresser plusieurs fichiers MDE, un fichier par version d'Access).

Important

Lors de l'installation, les fichiers de ShrinkerStretcher sont placés dans les documents partagés (All Users). Sur Windows XP, par exemple, vous les trouverez dans

C:\Documents and Settings\All users\Application Data\Peters
Software\ShrinkerStretcher

. Ce sera utile pour la suite...

Ajouter une référence à ShrinkerStretcher

Dans la version Démo, ShrinkerStretcher // qu'est-ce que c'est pénible à écrire, ce nom ! ;-) // est une bibliothèque externe (un fichier MDE) non modifiable. Pour que votre base de données puisse l'utiliser, vous devez lier la bibliothèque comme indiqué dans cet article. Concrètement :

Ouvrez votre base de données.
Faites apparaître Visual Basic Editor (vous pouvez par exemple taper Alt + F11).
Cliquez sur le menu Outils, puis sur l'option Références.
Cliquez sur le bouton Parcourir.
C'est ici qu'il faut chercher un peu : rappelez-vous que la bibliothèque se place dans les documents partagés. Sur Windows XP, cherchez dans C:\Documents and Settings\All users\Application Data\Peters Software\ShrinkerStretcher.
Il faut aussi que vous changiez le type de fichiers : "Tous les fichiers", au lieu de "Bibliothèques de types".
Apparaissent enfin plusieurs fichiers MDE (ou ACCDE pour Access 2007). Sélectionnez le bon, en fonction de votre version d'Access.

Cette opération n'est bien sûr à faire qu'une seule fois pour une base de données précise.

Configurer un formulaire

Il ne reste plus qu'à paramétrer un formulaire, pour qu'il change de taille automatiquement. Ceci va être fait via 2 petites lignes de Visual Basic :

Ouvrez votre formulaire en mode Création.
Faites apparaître les propriétés du formulaire, onglet Evénement.
Réglez l'événement Sur ouverture sur "Propriété événementielle", puis cliquez sur les points de suspension à droite.
Dans le bloc Sub / End Sub qui se présente, tapez :
SS_OnOpen Me
Repassez dans les propriétés du formulaire.
Réglez l'événement Sur redimensionnement sur "Propriété événementielle", puis cliquez sur les points de suspension à droite.
Dans ce nouveau bloc Sub / End Sub, tapez :
SS_OnResize Me, 1600, 1200

1600 et 1200 sont respectivement la largeur et la hauteur (en pixels) de l'écran sur lequel vous avez construit le formulaire. C'est grâce à ces 2 valeurs que ShrinkerStretcher peut calculer ses ratios pour redimensionner le formulaire. Si vous ne mettez aucune valeur, la résolution d'origine est supposée à 1024x768. Vous obtenez quelque chose comme ceci :

Private Sub Form_Open(Cancel As Integer)

  SS_OnOpen Me

End Sub

Private Sub Form_Resize()

  SS_OnResize Me, 1600, 1200

End Sub

C'est tout ! Passez en mode Formulaire. Vous remarquez que les objets du formulaires, les images, les polices sont adaptés à la taille du formulaire (donc de l'écran, par extension). Ce n'est pas forcément hyper fluide, mais ça a le mérite de fonctionner.
Il ne reste plus qu'à faire de même pour vos autres formulaires...

Importer plusieurs classeurs Excel dans une table Access en VBA

Hervé Inisan — Tue, 13 Jul 2010 20:28:00 +0200

Cet article fait suite à celui-ci : Importer plusieurs feuilles Excel dans une table Access en VBA.

Sur le même principe, on va voir ici comment importer les données de plusieurs classeurs Excel. Et pour garder la logique de l'article précédent, j'ai gardé la possibilité d'importer plusieurs feuilles de chaque classeur.

Le scénario

Je dispose de plusieurs classeurs Excel, dont les données doivent être importées dans Access. Pour que ça marche, les tableaux respectent un certain nombre de contraintes :

Les feuilles ont toutes la même structure (sinon, on ne va pas s'en sortir !).
Les feuilles peuvent avoir ou non des titres sur leur 1ère ligne (dans mon exemple, toutes les feuilles ont des titres).
La structure des feuilles correspond à la structure de ma table Access : les champs sont dans le même ordre, et les types de données sont compatibles.
Dans mon scénario, la 1ère colonne (Numéro Acteur) est clef primaire dans la table Access. Ça veut dire qu'il faut que les valeurs de Numéro Acteur, dans Excel, soient toutes différentes. Sinon, il y a aura des erreurs - normales - à l'importation.
Les classeurs sont tous placés dans le même dossier Windows.
Chaque classeur doit avoir le même nombre de feuilles à importer, et ces feuilles portent le même nom. Par exemple, si je veux importer les feuilles Acteurs1 et Acteurs2, tous les classeurs doivent avoir des feuilles portant ces noms.
Un classeur peut comporter d'autres feuilles (en nombre quelconque) qui ne seront pas concernées par l'importation.

Comme dans l'article précédent, la table Access a cette structure :

Le code

Voici une procédure VBA à recopier intégralement dans un module standard de votre base de données.

' ---

' IMPORTATION DE PLUSIEURS FEUILLES EXCEL,

' A PARTIR DE PLUSIEURS CLASSEURS

' ---

Sub ImportExcelMulti( _

  ByVal strChemin As String, _

  ByVal varFeuilles As Variant, _

  ByVal blnNoms As Boolean, _

  ByVal strTable As String _

  )

  ' Déclaration des variables

  Dim strClasseur As String

  Dim varFeuille As Variant

  ' Est-ce que le dossier existe ?

  strChemin = AddBackslash(strChemin)

  If Dir(strChemin, vbDirectory) = "" Then

    MsgBox "Le dossier ['" & strChemin & "] est introuvable.", vbExclamation

    Exit Sub

  End If

  ' Vidage de la table si nécessaire

  On Error GoTo ImportExcelErr

  If MsgBox("Souhaitez-vous vider la table [" & strTable & "] avant l'importation ?", _

    vbQuestion + vbYesNo) = vbYes Then

    CurrentDb.Execute "DELETE * FROM [" & strTable & "];"

  End If

  ' Parcourir tous les classeurs du dossier

  strClasseur = Dir(strChemin & "*.xls", vbNormal)

  While strClasseur <> ""

    ' Procédure d'importation

    For Each varFeuille In varFeuilles

      DoCmd.TransferSpreadsheet acImport, acSpreadsheetTypeExcel12, _

        strTable, strChemin & strClasseur, blnNoms, varFeuille & "!"

    Next

    ' Classeur suivant

    strClasseur = Dir

  Wend

  ' Un p'tit message pour terminer :-)

  MsgBox "Opération terminée !", vbInformation

  Exit Sub

ImportExcelErr:

  MsgBox "Erreur d'importation : " & Err.Description, vbExclamation

  Exit Sub

End Sub

Important

La fonction AddBackslash() doit aussi être présente dans un module de votre base de données.

La procédure ci-dessus doit recevoir 4 paramètres pour fonctionner :

Le chemin du dossier qui contient les classeurs Excel à importer.
Tous les classeurs sont supposés d'extension XLS, mais vous pouvez adapter en XLSX sur Excel 2007/2010.
La liste des feuilles à importer (au cas où certaines feuilles devraient être ignorées).
Le nom de la table Access de destination.
Une valeur booléenne (True / False) qui indique si les feuilles Excel ont des titres en première ligne.

Tester le code

Cette autre procédure (à recopier par exemple dans le même module) permet de tester l'import :

Sub TestImportExcelMulti()

  Dim varFeuilles As Variant

  ' Liste des feuilles Excel à importer

  varFeuilles = Array("Acteurs1", "Acteurs2")

  ' Importation proprement dite

  ImportExcelMulti "C:\Users\Hervé\Documents\Classeurs Excel", _

    varFeuilles, True, "tbl Acteurs - Import"

End Sub

Bien sûr, vous adaptez les valeurs en fonction de votre configuration.
Exécutez ce deuxième bloc de code. Il vous sera demandé si vous souhaitez vider la table Access avant d'importer toutes les données.
Et hop !

Sauvegardes datées

Hervé Inisan — Fri, 09 Jul 2010 14:38:00 +0200

Je souhaiterais automatiser la sauvegarde de ma base de données, en dupliquant le fichier MDB de temps en temps. Pour différencier les sauvegardes, l'idéal serait de dater chaque copie. Comment faire ?

Quelques pré-requis

Le code VBA qui suit utilise plusieurs fonctions qui ont déjà été traitées sur le blog. Commencez par les collecter dans un module standard, si ce n'est pas déjà le cas ! Voici la liste de ces fonctions :

Quelques structures utiles

Pour son fonctionnement, la fonction BackupFile() donnée plus bas a aussi besoin d'une énumération et d'un type de données personnalisé. Du coup :

Ajoutez un module standard à votre base de données.
Recopiez ceci en début du module :

' ---

' RESULTAT DE BACKUP

' ---

'

Public Enum BackupResult

  BackupOk = 0

  SourceNotFound = 1

  TargetDirNotFound = 2

  TargetAlreadyExists = 3

  Unknown = 4

End Enum

' ---

' INFORMATION DE BACKUP

' ---

Public Type BackupInfo

  ResultCode As BackupResult

  TargetPath As String

End Type

La fonction de sauvegarde

A la suite de votre module, ajoutez tout ça :

' ---

' SAUVEGARDE DATEE D'UN FICHIER

' ---

'

Function BackupFile( _

  ByVal strSourcePath As String, _

  Optional ByVal strTargetDir As String = "", _

  Optional ByVal blnForceReplace As Boolean = False) _

  As BackupInfo

  ' Quelques variables...

  Dim strTargetPath As String

  Dim fso As Object

  ' Quelques vérifications

  On Error GoTo BackupFileErr

  If Dir(strSourcePath) = "" Then

    BackupFile.ResultCode = SourceNotFound

    Exit Function

  End If

  ' Chemin de destination

  strTargetDir = IIf(strTargetDir = "", _

    FilePath(strSourcePath), _

    AddBackslash(strTargetDir))

  If Dir(strTargetDir, vbDirectory) = "" Then

    BackupFile.ResultCode = TargetDirNotFound

    Exit Function

  End If

  ' Fichier de destination

  strTargetPath = StringFormat("{0}BACKUP {1} {2}.{3}", _

    strTargetDir, _

    Format(Now(), "yyyymmdd-hhnnss"), _

    FilenameWithoutExt(strSourcePath), _

    FileExt(strSourcePath))

  BackupFile.TargetPath = strTargetPath

  ' Est-ce le fichier de destination existe déjà ?

  If (Dir(strTargetPath) <> "") And (Not blnForceReplace) Then

    BackupFile.ResultCode = TargetAlreadyExists

    Exit Function

  End If

  ' Copie du fichier via FSO

  Set fso = CreateObject("Scripting.FileSystemObject")

  fso.CopyFile strSourcePath, strTargetPath

  Set fso = Nothing

  ' Résultat final

  BackupFile.ResultCode = BackupOk

  Exit Function

BackupFileErr:

  BackupFile.ResultCode = Unknown

  Exit Function

End Function

La fonction prend en charge la copie d'un fichier, et date la copie automatiquement. Un fichier test.mdb sera dupliqué sous le nom BACKUP 20101225-153017 test.mdb, si la copie a été lancée le 25/12/2010 à 15:30:17. Le fait de descendre au niveau des secondes permet de générer autant de sauvegardes que nécessaire. Vous pouvez aménager le format si ça fait trop !

La création du chemin de la copie est également un peu détaillée, mais ça permettra un peu de souplesse si vous voulez une extension personnalistée (.bak au lieu de .mdb, par exemple).

La fonction reçoit 3 paramètres, seul le premier est obligatoire :

Le chemin complet du fichier à sauvegarder. Le fichier n'est pas forcément un MDB, ça peut être en fait n'importe quoi !
Le chemin du dossier de destination. Si ce chemin n'est pas donné, la copie se fera dans le même dossier que l'original.
Une valeur booléenne qui faut True s'il faut écraser le fichier de copie (lorsqu'il existe déjà). Devrait servir rarement...

Test #1

Pour tester la fonction directement :

Ouvrez la fenêtre Exécution (CTRL + G).
Tapez dedans :
? BackupFile(CurrentProject.FullName).ResultCode

Vous devez obtenir un résultat de 0, qui dit que tout s'est bien passé. Et bien sûr, une copie datée de votre base de données devrait se trouver dans le même dossier.

Test #2

La fonction BackupFile() n'affiche volontairement aucun message. Elle gère juste le "bas niveau" et renvoie un code de résultat. Vous pouvez utiliser ceci pour afficher des messages clairs à l'utilisateur :

' ---

' SAUVEGARDE DATEE DE LA BASE DE DONNEES

' ---

Sub BackupDB()

  Dim bi As BackupInfo

  ' Dupliquer la base dans un sous-dossier Backup

  ' et récupérer le code de résultat

  bi = BackupFile(CurrentProject.FullName, _

    CurrentProject.Path & "\Backup")

  ' Afficher un message en fonction du résultat

  Select Case bi.ResultCode

    ' OK

    Case BackupResult.BackupOk:

      MsgBox "Opération terminée." _

        & vbCrLf & vbCrLf & "La sauvegarde est disponible à cet emplacement :" _

        & vbCrLf & bi.TargetPath, vbInformation

    ' Fichier source introuvable

    Case BackupResult.SourceNotFound:

      MsgBox "Fichier source introuvable !", vbExclamation

    ' Dossier destination introuvable

    Case BackupResult.TargetDirNotFound:

      MsgBox "Dossier destination introuvable !", vbExclamation

    ' Fichier destination déjà existant

    Case BackupResult.TargetAlreadyExists:

      MsgBox "Le fichier de destination existe déjà !", vbExclamation

    ' Erreur indéterminée

    Case BackupResult.Unknown

      MsgBox "Une erreur non identifiée s'est produite.", vbExclamation

  End Select

End Sub

Dans cet exemple, je suppose que les sauvegardes doivent être faites dans un sous-dossier Backup, placé au même emplacement que la base MDB.

Pour finir...

Il ne reste plus qu'à...

Créer un bouton, sur un formulaire.
Nommer ce bouton proprement.
Définir l'événement Sur clic du bouton de cette manière :

Private Sub btnBackup_Click()

  BackupDB

End Sub

Recherche de mot entier

Hervé Inisan — Thu, 08 Jul 2010 16:23:00 +0200

Comment trouver un mot entier dans une requête Access ? Par exemple, dans une phrase comme "Bonjour, aujourd'hui, c'est le jour de Noël !", je souhaite vérifier si la phrase contient le mot "jour".

Un critère comme [Le champ] LIKE '*jour*' semble une bonne idée, mais le critère m'extrait les mots Bonjour, Aujourd'hui et Jour. Alors que je ne souhaite extraire que le mot Jour. Une phrase comme "Bonjour, c'est Noël" serait considérée comme valide, et je n'en veux pas. Comment faire ?

Le problème des délimiteurs

Avec un peu d'astuce, on peut imaginer des critères du style : [Le champ] LIKE '* jour *'
avec des espaces autour du mot jour. Dans ce cas, Bonjour et Aujourd'hui sont effectivement éliminés.

Mais comment faire s'il y a un point, une virgule ou un tiret avant/après le mot "jour" ? Du genre : "Ce jour-là...". Le nombre de variantes devient lourd à gérer, et on sent que ça va donner un critère SQL long comme un jour sans ordinateur. :-)

Les expressions régulières à la rescousse

C'est ici qu'il faut se rabattre sur les expressions régulières, dont il a été question dans d'autres articles du blog. Consultez notamment l'article Valider la saisie d'une adresse e-mail pour voir comment inscrire la bibliothèque VBScript Regular Expressions dans votre projet VBA.

La fonction VBA

Une fois la bibliothèque activée, recopiez cette fonction dans un module standard de votre base de données :

Function RechercheMot( _

  ByVal strChaine As String, _

  ByVal strMot As String) As Boolean

  ' On crée une expression rationnelle

  Dim re As VBScript_RegExp_55.RegExp

  Set re = New RegExp

  ' On définit le critère à respecter pour un mot entier

  re.Pattern = "\b" & strMot & "\b"

  re.IgnoreCase = True

  ' La fonction Test renvoie True si la chaîne

  ' respecte le critère

  RechercheMot = re.Test(strChaine)

  Set re = Nothing

End Function

Quelques explications :

Si votre mot est jour, on va effectuer une recherche par l'expression régulière \bjour\b.
Le \b détecte les limites (boundaries en anglais) d'un mot. Une limite pouvant être un espace, une tabulation, un tiret, un début de chaîne, une fin de chaîne.
En résumé, on cherche le mot jour compris entre des limites quelconques, mais pas collé à une autre portion de texte !

Tester la fonction

Pour tester la fonction rapidement :

Faites apparaître la fenêtre Exécution (CTRL + G).
Tapez-y des choses comme ça, en validant chaque ligne par [Entrée] :

La fonction renvoie Vrai quand la phrase inspectée contient le mot entier, et Faux sinon.
Vous remarquerez que les majuscules/minuscules ne sont pas importantes dans la recherche. Si vous souhaitez faire la distinction, remplacez re.IgnoreCase = True par re.IgnoreCase = False dans le listing plus haut.

Mettre la fonction en application

Tout ça devient plus intéressant dans une requête : je reprends ma base de films, et je voudrais trouver tous les films dont le résumé contient le mot "Elu". Première approche :

On obtient :

Le problème des 2 premiers films est que leur résumé contient le mot "celui", qui répond au critère. Aménageons la requête en ajoutant un champ calculé qui fait appel à la fonction VBA du dessus :

Cette fois, ça marche : seul Matrix sort dans les résultats. On a trouvé l'Elu !

Qu'est-ce que "Me" en langage VBA ?

Hervé Inisan — Thu, 08 Jul 2010 14:50:00 +0200

Si vous débutez en programmation VBA, vous avez dû voir trainer le mot-clef Me dans plusieurs bouts de code. A quoi sert ce mot-clef ? Quand peut-on l'utiliser ? Quand ne doit-on pas l'employer ?

About Me

En programmation objet, Me désigne l'instance de classe dans laquelle on se trouve.
Euh... si vous êtes débutant, ce genre de phrase ne va pas vous aider !

Pour faire mieux (quoique !) :

Dans Access, le formulaire,par exemple, est un objet type, standard (une "classe", nommée précisément Access.Form).
Lorsque vous construisez un formulaire personnalisé (un formulaire Clients ou Produits, par exemple), vous créez une variante du formulaire type.
Et lorsque vous ouvrez le formulaire Clients et le formulaire Produits, ces 2 objets précis "vivent" en simultané à l'écran. Ils n'ont pas les mêmes réglages, pas les mêmes données, etc. Ce sont ces 2 objets qu'on appelle des instances.
Pour faire référence à l'une ou l'autre des instances, en VBA, vous écrivez Forms![frm Clients] et Forms![frm Produits], par exemple.
Maintenant, si vous devez taper du code VBA dans le formulaire Clients, ce code fera souvent référence au formulaire Client lui-même. C'est ici qu'intervient Me : plutôt que d'écrire Forms![frm Clients], utilisez Me ("moi" ; sous-entendu : le formulaire dans lequel se trouve le code VBA).
Si vous avez suivi, lorsque Me est placé dans le VBA du formulaire Produits, il équivaut à Forms![frm Produits].

Info

Dans les langages inspirés du C++ (C++ bien sûr, mais aussi Java, C#, PHP...), l'équivalent de Me s'appelle this.

Où peut-on rencontrer Me ?

Comme Me désigne une instance de classe, il ne peut être utilisé que dans du code VBA reposant sur des classes. Concrètement, vous ne pouvez utiliser Me que dans :

Un module de formulaire
Dans ce cas, Me désigne l'objet Formulaire en question (donc une instance de la classe Access.Form).
Un module d'état
Dans ce cas, Me désigne l'objet État en question (une instance de la classe Access.Report).
Un module de classe VBA
Dans ce cas, Me désigne l'instance de classe concernée.

Attention

Les modules standard ne sont pas des modules de classe (par définition !). Donc, vous ne pouvez pas utiliser Me dans ces modules.

A quoi ça sert ?

Me est d'abord un raccourci d'écriture. Imaginez ce bout de code qui modifie la légende de 2 formulaires :

Sub Test()

  Forms![frm Clients].Caption = "Test 1"

  Forms("frm Produits").Caption = "Test 2"

End Sub

Le code donne 2 variantes d'écriture équivalentes (avec crochets ou avec parenthèses). Si ce code est tapé hors des formulaires frm Clients et frm Produits (par exemple dans un module standard), il ne doit pas être modifié, puisque vous "pilotez" en quelque sorte des formulaires de l'extérieur. Il faut donc spécifier le chemin complet pour accéder à chaque formulaire.

Imaginons maintenant que le code soit tapé dans le formulaire Clients. Étant donné qu'on se trouve dans le formulaire lui-même, il n'est plus utile de le nommer entièrement. On peut donc simplifier en :

Sub Test()

  Me.Caption = "Test 1"

  Forms("frm Produits").Caption = "Test 2"

End Sub

La deuxième ligne reste inchangée, puisqu'on ne se trouve pas dans le formulaire Produits (il faut pointer ce formulaire explicitement).

Comme on l'a dit plus haut, le premier avantage est que le code est plus court à écrire, donc plus efficace.
Autre côté pratique : si vous renommez frm Clients en frm Customers, le 2ème listing fonctionne toujours. Alors que l'exemple plus haut lèvera une erreur. Il donc plus facile de faire évoluer la base de données.

Liste des tables - Version 2

Hervé Inisan — Thu, 08 Jul 2010 10:03:00 +0200

Voici une suite à l'article "Liste des tables" paru l'année dernière. Dans cette article, il était question d'afficher la liste des tables Access dans la fenêtre Exécution. Question d'un lecteur sur cet article : "peut-on faire autre chose de cette liste, au lieu de simplement l'afficher dans la fenêtre Exécution ?". Voici qui devrait donner de nouvelles pistes...

Application 1 : afficher les tables dans une liste de formulaire

Dans cet exemple, on choisit afficher les tables sur un formulaire, dans une liste (ListBox). Pour cela :

Construisez le formulaire.
Placez sur le formulaire une liste (ou une liste déroulante) : objets ListBox ou ComboBox.
A l'aide des propriétés, nommez cette liste lstTables.
Toujours dans les propriétés de la liste, onglet Données, réglez la propriété Origine Source sur Liste Valeurs. Sinon, il sera impossible d'ajouter des éléments à la liste de façon dynamique.
Programmez ceci dans l'événement Sur ouverture du formulaire :

Private Sub Form_Open(Cancel As Integer)

  Dim db As DAO.Database, tdf As DAO.TableDef

  Set db = CurrentDb

  For Each tdf In db.TableDefs

    If (tdf.Attributes And dbSystemObject) = 0 Then

      Me.lstTables.AddItem tdf.Name

    End If

  Next tdf

  Set db = Nothing

End Sub

A l'ouverture, vous obtenez ceci :

Reste maintenant à trouver quoi faire des tables, mais ce n'est pas le sujet de cet article ! :-)

Note

La méthode AddItem n'existe pas dans les Access antérieurs à 2002. Si c'est votre cas, consultez cet autre article du blog.

Application 2 : stocker la liste des tables... dans une table

Dans l'exemple précédent, la liste de tables est alimentée directement en VBA. Vous pouvez aussi stocker la liste des tables dans une autre table. Comme beaucoup de "constructions" Access sont basées sur des tables, on peut imaginer toutes sortes de traitements ensuite (voir plus bas).

Dans mon cas, j'ai préparé une table tbl Tables (ben oui, le nom est moyen :-)), qui comporte au moins un champ Nom Table.
Recopiez ce code dans un module standard de la base de données :

Function StockageListeTables()

  Dim db As DAO.Database

  Dim tdf As DAO.TableDef

  Dim rst As DAO.Recordset

  ' La base de données en cours

  Set db = CurrentDb

  ' Vider la liste actuelle des tables

  db.Execute "DELETE * FROM [tbl Tables];"

  ' La table de stockage

  Set rst = db.OpenRecordset("tbl Tables", dbOpenDynaset)

  ' Parcourir la liste des tables et les stocker

  ' On stocke toutes les tables sauf :

  ' - les table systèmes

  ' - la table tbl Tables

  For Each tdf In db.TableDefs

    If ((tdf.Attributes And dbSystemObject) = 0) _

      And (tdf.Name <> "tbl Tables") Then

      rst.AddNew

      rst("Nom Table") = tdf.Name

      rst.Update

    End If

  Next tdf

  ' On ferme !

  rst.Close

  Set rst = Nothing

  Set db = Nothing

End Function

Pour exécuter ce code, vous pouvez ensuite :

Placer un bouton sur un formulaire.
Programmer l'événement Sur clic du bouton en y tapant :

Private Sub MonBouton_Click()

  StockageListeTables

End Sub

Une fois le bouton cliqué, la table de stockage contient :

Applications dérivées

Maintenant que les tables sont listées... dans une table, on peut utiliser tbl Tables pour :

Construire des requêtes
Construire des formulaires
Construire des états
D'autres idées ?

Voici par exemple un état vite fait basé sur tbl Tables :

Double-clic dans les listes déroulantes

Hervé Inisan — Wed, 07 Jul 2010 18:21:00 +0200

Le saviez-vous ?

Dans Access, il y a plein de réglages qui se font par listes déroulantes. Parmi eux :

Choisir un tri croissant ou décroissant dans une requête.
Choisir les barres de défilement d'un formulaire (barre verticale, barre horizontale, les deux, aucune).
Régler des propriétés de table (Null interdit = Oui ou Non).

La liste n'est pas exhaustive, y en a plein !
Juste un petit truc rapide : au lieu de dérouler la liste, vous pouvez généralement double-cliquer dedans. Ce qui a pour effet de sélectionner la valeur suivante dans la liste.

Par exemple, si vous double-cliquez dans un tri vide, ci-dessus, vous obtenez "Croissant". Un autre double-clic donne "Décroissant". Un 3ème double-clic vide le tri. Pratique dans certains cas (notamment pour les valeurs Oui/Non).

Tester une connexion avec le serveur

Hervé Inisan — Tue, 06 Jul 2010 16:05:00 +0200

Comment vérifier que le serveur qui héberge ma base de données est bien accessible ?

Principe

Lorsque vous travaillez en réseau sur Access, vous scindez généralement votre application en 2 : une base frontale (qui contient les requêtes, formulaires, états, macros, modules) et une base dorsale (qui contient les tables et les relations). La base frontale est située sur chaque poste utilisateur, la base dorsale est par contre placée sur le serveur.

Vous aurez peut-être besoin, dans la base frontale, de vérifier si le serveur - ou la base dorsale - est accessible. Notamment dans le cas où vous souhaitez recréer les liaisons de tables. Voici une fonction qui va aider.

Information

Pour plus de détails sur la mise en réseau d'une base Access, consultez la page Access en réseau.

Le code Visual Basic

Recopiez la fonction ci-dessous dans un module standard de votre base de données :

Function ServeurOK(ByVal strCheminBase As String) As Boolean

  Dim strFichier As String

  On Error Resume Next

  strFichier = Dir(strCheminBase)

  ServeurOK = (Err.Number = 0)

End Function

Tester le code

La fonction précédente doit recevoir un chemin de fichier (une base Access ou n'importe quel autre fichier, en fait). Elle renvoie True si le fichier existe à l'emplacement donnée, False sinon. Pour la tester, écrivez ceci dans une procédure ou une fonction VBA :

If ServeurOK("\\Serveur\Dossier\base_dorsale.mdb") Then

  MsgBox "Serveur ok"

Else

  MsgBox "Pas de serveur"

End If

où :

Serveur est le nom (ou l'adresse IP) de votre serveur.
Dossier est le nom du dossier partagé qui contient la base MDB (il peut y avoir plusieurs niveaux : \\Serveur\Dossier1\Dossier2).
base_dorsale.mdb est le nom de votre... base Access dorsale.

Modifier l'état Majuscules/Minuscules (Caps Lock) du clavier en VBA

Hervé Inisan — Mon, 14 Jun 2010 08:55:00 +0200

Peut-on forcer l'état du clavier en majuscules (ou minuscules), en VBA ?

Avant toute chose

Ce qui suit ne devrait pas servir souvent. Sur Access, il y a plusieurs autres techniques "natives" pour transformer une saisie en majuscules, elles sont traitées dans cet autre article du Grenier. Ce sont ces techniques qu'il faut privilégier, sauf cas particulier bien sûr.

Ici, il est question de forcer le passage du clavier en majuscules (la même chose que d'appuyer sur la touche Verr. MAJ - ou Caps Lock - du clavier).

Un exemple de cas spécifique, dont il a été question sur les forums du site : forcer le clavier automatiquement pour utiliser un modèle de scanner de code barre où les caractères doivent être inscrits en majuscules.

Le code

Recopiez tout le code VBA ci-dessous dans un module standard de votre base de données :

' Fonctions API

Private Declare Function GetKeyboardState Lib "user32" (kbArray As KeyboardBytes) As Long

Private Declare Function SetKeyboardState Lib "user32" (kbArray As KeyboardBytes) As Long

' Structure pour stocker les infos clavier

Private Type KeyboardBytes

     kbByte(0 To 255) As Byte

End Type

' Enumération pour les états de clavier

Enum CapsLockOnOff

    CapsLockOff = 0

    CapsLockOn = 1

End Enum

Dim kbArray As KeyboardBytes

' ---

' CHANGEMENT D'ETAT DU CLAVIER

' ---

'

Public Sub SetCapsLock(c As CapsLockOnOff)

    GetKeyboardState kbArray

    kbArray.kbByte(&H14) = c

    SetKeyboardState kbArray

End Sub

Tester

Dans l'événement Sur clic d'un bouton (ou à tout autre endroit qui vous convient !), tapez ceci pour passer le clavier en majuscules :

SetCapsLock CapsLockOn

Et si vous souhaitez passer le clavier en minuscules, tapez plutôt :

SetCapsLock CapsLockOff

Note

Le code VB ci-dessus n'a pas d'effet sur la lumière "Caps Lock" du clavier.

Forcer une saisie en majuscules dans un champ Access

Hervé Inisan — Fri, 11 Jun 2010 15:03:00 +0200

Comment forcer une saisie en majuscules (ou inversement en minuscules) dans un champ de table Access ?

Première technique

La première technique consiste à intervenir directement au niveau du champ de table, grâce à la propriété "Masque de saisie". Pour cela :

Ouvrez votre table en mode Création.
Placez-vous sur le champ concerné.
Dans les propriétés, renseignez le masque de saisie de cette manière :
>CCCCCCCCCC

Ce qu'il faut savoir :

Dans un masque de saisie, le symbole C désigne n'importe quel caractère ou espace, en saisie facultative. Dans mon exemple, je suppose que le champ à forcer en majuscules fait donc 10 caractères facultatifs (puisque j'ai placé 10 fois le symbole C). Si votre champ fait 30 caractères de long, vous devez placer 30 fois la lettre C. Comme les caractères sont facultatifs, rien n'empêchera l'utilisateur de taper un mot de 5 lettres uniquement.
Pour rendre les caractères obligatoires, vous utiliseriez le symbole & à la place de C.
Et surtout : le signe > force la transformation en majuscules des caractères qui le suivent. Dans mon exemple, il est placé en début de masque, ce qui veut dire que les 10 caractères qui suivront seront convertis en majuscules.
Pour forcer une conversion en minuscules, vous utiliseriez le signe <.
Du coup, un masque comme >C<CCCC signifierait : forcer la 1ère lettre (facultative) en majuscule, et les 4 suivantes (facultatives aussi) en minuscules.

Conseil

Pour obtenir la liste des caractères autorisés dans un masque de saisie, consultez l'aide d'Access.

Deuxième technique

La méthode précédente est rapide, assez simple à mettre en place, et elle a le mérite de se placer au niveau de la table. Mais elle a aussi quelques inconvénients à mon goût :

Le fait de taper tous ces symboles, c'est loooong !
Si je décide ultérieurement d'agrandir la taille du champ, il faut que je pense à ajouter d'autres caractères C dans le masque de saisie.

Du coup, voici une autre façon de faire, cette fois au niveau du formulaire :

Ouvrez le formulaire qui sert à alimenter la table, en mode Création.
Faites apparaître les propriétés du formulaire, onglet Evénement.
Cliquez dans l'événement Avant MAJ, et réglez-le sur "Procédure événementielle", à l'aide de sa liste déroulante.
Cliquez sur les points de suspension à droite de l'événement, vous arrivez dans un bloc Visual Basic.
Enfin, tapez quelque chose comme ceci (vous aménagez en fonction de vos noms de champs) :
Me.Nom_Acteur = UCase(Me.Nom_Acteur)
ou :
Me![Nom Acteur] = UCase(Me![Nom Acteur]

Dans mon cas, le champ à forcer en majuscules s'appelle Nom Acteur. C'est la fonction VBA UCase() qui effectue la conversion. La conversion se fera systématiquement avant que la saisie soit transférée dans la table.

Importer plusieurs feuilles Excel dans une table Access en VBA

Hervé Inisan — Fri, 04 Jun 2010 12:03:00 +0200

Je dispose de plusieurs feuilles Excel (de même structure), et je souhaiterais les importer toutes dans une seule table Access. Comment faire ?

Le scénario

Dans un classeur Excel (Acteurs.xlsx), je dispose de 5 feuilles qui ont cette forme :

Les feuilles ont toutes la même structure (sinon, on ne va pas s'en sortir !).
Les feuilles peuvent avoir ou non des titres sur leur 1ère ligne (dans mon exemple, toutes les feuilles ont des titres).
La structure des feuilles correspond à la structure de ma table Access : les champs sont dans le même ordre, et les types de données sont compatibles.
Dans mon scénario, la 1ère colonne (Numéro Acteur) est clef primaire dans la table Access. Ça veut dire qu'il faut que les valeurs de Numéro Acteur, dans Excel, soient toutes différentes. Sinon, il y a aura des erreurs - normales - à l'importation.

La table Access a donc cette forme :

Bien sûr, par Copier/Coller, je pourrais rassembler ces feuilles en 1 seule, et importer la feuille résultante dans Access. Mais ce n'est pas pratique...

si le nombre de feuilles est important ;
si l'opération doit être faite régulièrement et manuellement (voir cet autre article du blog pour l'approche manuelle) ;
si le nombre de lignes total dépasse le nombre de lignes d'Excel. Dans Excel 2007 et 2010, ça devrait aller, mais on est limité à 65536 dans Excel 97 à 2003.

Le code

Voici une procédure VBA à recopier intégralement dans un module standard de votre base de données.

' ---

' IMPORTATION DE PLUSIEURS FEUILLES EXCEL

' ---

Sub ImportExcel( _

  ByVal strChemin As String, _

  ByVal varFeuilles As Variant, _

  ByVal blnNoms As Boolean, _

  ByVal strTable As String _

  )

  ' Déclaration des variables

  Dim strFeuille As Variant

  ' Est-ce que le classeur Excel existe ?

  If Dir(strChemin) = "" Then

    MsgBox "Le classeur ['" & strChemin & "] est introuvable.", vbExclamation

    Exit Sub

  End If

  ' Vidage de la table si nécessaire

  On Error GoTo ImportExcelErr

  If MsgBox("Souhaitez-vous vider la table [" & strTable & "] avant l'importation ?", _

    vbQuestion + vbYesNo) = vbYes Then

    CurrentDb.Execute "DELETE * FROM [" & strTable & "];"

  End If

  ' Procédure d'importation

  For Each strFeuille In varFeuilles

    DoCmd.TransferSpreadsheet acImport, acSpreadsheetTypeExcel12, _

      strTable, strChemin, blnNoms, strFeuille & "!"

  Next

  ' Un p'tit message pour terminer :-)

  MsgBox "Opération terminée !", vbInformation

  Exit Sub

ImportExcelErr:

  MsgBox "Erreur d'importation : " & Err.Description, vbExclamation

  Exit Sub

End Sub

La procédure ci-dessus doit recevoir 4 paramètres pour fonctionner :

Le chemin complet du classeur Excel à importer.
La liste des feuilles à importer (au cas où certaines feuilles devraient être ignorées).
Le nom de la table Access de destination.
Une valeur booléenne (True / False) qui indique si les feuilles Excel ont des titres en première ligne.

Tester le code

Le code ci-dessus prend en charge la procédure d'importation. Il ne reste plus qu'à le tester : écrivez cette autre procédure (pourquoi pas dans le même module), qui va appeler le code d'importation :

Sub TestImportExcel()

  Dim varFeuilles As Variant

  ' Liste des feuilles Excel à importer

  varFeuilles = Array("Acteurs1", "Acteurs2", _

    "Acteurs3", "Acteurs4", "Acteurs5")

  ' Importation proprement dite

  ImportExcel "C:\Users\Hervé\Documents\Acteurs.xlsx", _

    varFeuilles, True, "tbl Acteurs - Import"

End Sub

Automatiser l'impression d'un classeur Excel en PDF via PDFCreator

Hervé Inisan — Sun, 16 May 2010 14:05:00 +0200

Suite à l'article Automatiser l'impression d'un état en PDF via PDFCreator, un lecteur du blog m'a demandé si c'était possible de faire la même chose pour Excel uniquement. Il faut juste quelques petits aménagements pour transformer le code Access en un code Excel. Voici donc, pour une fois, un article qui s'applique uniquement à Excel...

Si vous avez manqué le début...

Consultez l'article cité plus haut avant toute chose. Vous y verrez comment, dans votre projet Excel, faire une référence à la bibliothèque PDFCreator.

Le code VBA

Voici la procédure VBA adaptée de l'article précédent, et adaptée spécifiquement pour Excel. Recopiez tout ce code dans un module standard de votre classeur Excel (ou dans le classeur de macros personnelles, si vous souhaitez le réutiliser souvent).

Option Explicit

' Ne pas oublier de cocher la bibliothèqe PDFCreator

' dans le menu Outils / Références de Visual Basic Editor

' API Windows pour faire une temporisation en millisecondes

Private Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)

' Constantes pour les temporisations

Private Const maxTime = 10    ' en secondes

Private Const sleepTime = 250 ' en millisecondes

' ---

' IMPRESSION D'UN CLASSEUR EXCEL EN PDF

' ---

' Entrée : strPDFName    <- Nom du fichier PDF à générer (facultatif)

'                           En l'absence de nom de fichier, le PDF

'                           généré reprend le nom du classeur Excel.

'          strDirectory  <- Chemin de stockage du fichier PDF (facultatif)

'

Public Sub SaveAsPDF( _

  Optional ByVal strPDFName As String = "", _

  Optional ByVal strDirectory As String = "")

  ' Quelques variables...

  Dim pdfc As PDFCreator.clsPDFCreator

  Dim DefaultPrinter As String

  Dim c As Long

  Dim OutputFilename As String

  ' Instancier un nouvel objet PDFCreator

  Set pdfc = New clsPDFCreator

 ' Paramétrer l'objet PDFCreator

  With pdfc

    .cStart "/NoProcessingAtStartup"

    .cOption("UseAutosave") = 1

    .cOption("UseAutosaveDirectory") = 1

    ' Chemin de destination

    ' Par défaut : dossier 'Mes documents' de l'utilisateur

    If strDirectory = "" Then

      strDirectory = Environ("USERPROFILE") & "\Mes documents\"

    End If

    .cOption("AutosaveDirectory") = strDirectory

    ' Nom du fichier PDF à générer

    .cOption("AutosaveFilename") = _

      IIf(strPDFName = "", ActiveWorkbook.Name, strPDFName)

    ' Format de sauvegarde (0 = PDF)

    .cOption("AutosaveFormat") = 0

    ' Mémoriser l'imprimante par défaut

    ' et définir PDFCreator à la place

    DefaultPrinter = .cDefaultPrinter

    .cDefaultPrinter = "PDFCreator"

    .cClearCache

    ' Imprimer les feuilles sélectionnées

    ActiveWindow.SelectedSheets.PrintOut Copies:=1, Collate:=True

    .cPrinterStop = False

  End With

  ' Temporisation

  c = 0

  Do While (pdfc.cOutputFilename = "") And (c < (maxTime * 1000 / sleepTime))

    c = c + 1

    Sleep 200

  Loop

  ' Nom du fichier PDF produit

  OutputFilename = pdfc.cOutputFilename

  ' Réinstaller l'imprimante d'origine

  With pdfc

    .cDefaultPrinter = DefaultPrinter

    Sleep 200

    .cClose

  End With

  ' Attendre jusqu'à ce que PDFCreator soit supprimé de la mémoire

  Sleep 2000

  ' Vérifier si le fichier a été créé

  If OutputFilename = "" Then

    MsgBox "Création du fichier PDF." & vbCrLf & vbCrLf & _

      "Une erreur s'est produite : temps écoulé !", vbExclamation + vbSystemModal

  End If

End Sub

Exemple 1

La procédure reçoit 2 paramètres en entrée, les 2 étant facultatifs :

Le nom du fichier PDF à générer. Par défaut, le nom du classeur sera repris, sinon.
Le dossier de stockage du PDF. Par défaut, il s'agit du dossier Documents de l'utilisateur. Si vous travaillez sur Windows Vista ou 7, remplacez le "\Mes documents\" par "\Documents", dans le code, sinon ça ne marchera pas.

Voici un exemple d'appel simple du code VBA :

Public Sub Test1()

  ' Imprimer seulement la feuille en cours

  Sheets("Feuil1").Select

  SaveAsPDF "test.pdf"

End Sub

Exemple 2

Voici un 2ème exemple. Cette fois, on sélectionne au préalable 2 feuilles du classeurs, pour les imprimer dans le même PDF :

Public Sub Test2() 

  ' Imprimer les feuilles Feuil1 et Feuil2

  Sheets(Array("Feuil1", "Feuil2")).Select

  SaveAsPDF "test2.pdf"

End Sub

Supprimer tout le code HTML d'une chaîne

Hervé Inisan — Mon, 26 Apr 2010 14:18:00 +0200

J'ai une chaîne de caractères contenant du code HTML. Comment supprimer tout ce code automatiquement ?

Le principe

Soit une chaîne de caractères contenant du code HTML. Par exemple :

<html><body>Ceci est un <b>test</b>.</body></html>

L'idée est d'extraire toutes les balises HTML pour ne conserver que la phrase :

Ceci est un test.

Version Access 2007

Access 2007 propose une fonction PlainText() qui va faire l'affaire :

Ouvrez la fenêtre Exécution (CTRL + G).
Tapez-y quelque chose comme ce qui suit, et tapez [Entrée].

? PlainText("<html><body>Ceci est un <b>test</b>.</body></html>")

Et c'est tout !

Version 2003 et inférieure

Si vous disposez d'un Access 2003 (ou moins), ce n'est pas si simple que ça : il faut passer par du VBA, détecter tout ce qui ressemble à une balise, enlever le superflu... tout ça quoi ! Une fois encore, les expressions rationnelles (appelées plus souvent "expressions régulières") vont nous sortir d'affaire. Pour la mise en place générale de la bibliothèque VBScript Regular Expressions, consultez le début de cet autre article.

La fonction VBA

Voici la fonction VBA qui va s'occuper du nettoyage :

' ---

' SUPPRESSION DES BALISES HTML D'UNE CHAINE

' ---

'

Function SupprimerHTML(ByVal strHTML As String) As String

  Dim re As VBScript_RegExp_55.RegExp

  ' On crée une expression rationnelle

  Set re = New RegExp

  ' On définit le critère qui cherche toute balise HTML

  re.Pattern = "<\s*?[^>]+\s*?>"

  ' On fait en sorte que la casse (majuscules/minuscules)

  ' soit indifférente

  re.IgnoreCase = True

  ' Traitement global (récursif)

  re.Global = True

  ' La fonction Test renvoie True si la chaîne

  ' respecte le critère

  SupprimerHTML = re.Replace(strHTML, "")

End Function

Tester la fonction

Une fois la fonction ci-dessus recopiée dans un module standard...

Ouvrez la fenêtre Exécution (CTRL + G).
Tapez-y quelque chose comme ce qui suit, et tapez [Entrée].

? SupprimerHTML("<html><body>Ceci est un <b>test</b>.</body></html>")

Tadaaa !

Extraire une portion de page HTML à partir d'Access

Hervé Inisan — Sun, 25 Apr 2010 15:36:00 +0200

Dans l'épisode précédent (Enregistrer une page HTML à partir d'Access), vous avez vu comment enregistrer une page Web entière sur disque. Cette fois, on va essayer d'extraire seulement une portion de la page.

Le principe

Une page HTML est décomposée en blocs, délimités par des balises HTML comme body, div, table, etc. Ces blocs sont imbriqués les uns dans les autres. Certains blocs - souvent importants, et en principe uniques sur une page - sont en général nommés par un identifiant (id). Par exemple, la zone centrale de ce blog est une division HTML nommée content.

C'est le code source de la page HTML qui nous donne le fameux id :

Notre objectif est d'extraire le texte de tous les articles du bloc content, en éliminant les bandes latérales du site. A partir de l'id, et en utilisant la méthode DOM getElementById(), on peut extraire la portion de HTML souhaitée.

Le code VBA

La fonction VBA ci-dessous est donc directement dérivée de celle de l'article précédent :

' ---

' SAUVEGARDE D'UNE PORTION DE PAGE WEB

' A L'AIDE DE INTERNET EXPLORER

' ---

'

Function EnregistrerBlocHTML( _

  ByVal strURL As String, _

  ByVal strFichier As String, _

  ByVal strID As String) As Boolean

  ' Démarrer et afficher Internet Explorer

  On Error GoTo EnregistrerHTMLErr

  Dim ie As Object

  Set ie = CreateObject("InternetExplorer.Application")

  ' Naviguer vers l'adresse souhaitée

  ' et attendre qu'elle soit chargée

  ie.navigate strURL

  While ie.Busy

    DoEvents

  Wend

  ' Extraire la zone demandée (par son ID)

  Dim doc As MSHTML.HTMLDocument

  Dim bloc As MSHTML.IHTMLElement

  Set doc = ie.Document

  Set bloc = doc.getElementById(strID)

  If bloc Is Nothing Then

    EnregistrerBlocHTML = False

    Exit Function

  End If

  ' Créer et ouvrir le fichier texte

  Dim intHandle As Integer

  intHandle = FreeFile

  Open strFichier For Output As #intHandle

  ' Ecrire le contenu HTML de la page Web dans le fichier

  Print #intHandle, bloc.innerHTML

  ' Fermer le fichier et Internet Explorer

  Close #intHandle

  Set bloc = Nothing

  Set doc = Nothing

  ie.Quit

  ' Renvoyer un code de succès

  EnregistrerBlocHTML = True

  Exit Function

EnregistrerHTMLErr:

  MsgBox "Erreur : " & Err.Description, vbExclamation

  EnregistrerBlocHTML = False

  Exit Function

End Function

La fonction accepte 3 arguments :

Le 1er paramètre de la fonction est l'adresse de la page Web à visiter.
Le 2ème paramètre est le chemin complet du fichier à créer sur votre disque.
Attention : si le fichier pointé existe, il sera écrasé sans avertissement. Vous pouvez toujours améliorer le code ! :-)
Le 3ème paramètre est l'identifiant (id) du bloc HTML à extraire.
La fonction fournie renvoie True si la sauvegarde du bloc HTML a pu se faire correctement, et False sinon.

Important

L'exemple de code ci-dessus fait appel à la bibliothèque MSHTML (Microsoft HTML Object Library). Cette bibliothèque doit être associée à votre base de données pour que le programme fonctionne.

Pour plus de détails sur les références, consultez cette page.

Tester la fonction

Pour tester la fonction rapidement, utilisez la fenêtre Exécution :

Appuyez sur CTRL + G.
Tapez dans la fenêtre Exécution quelque chose comme :
? EnregistrerHTML("http://grenier.self-access.com", "C:\Documents and Settings\Hervé\Mes documents\grenier.html", "content")
Bien sûr, vous aménagez le chemin du fichier en fonction de votre propre identifiant de session Windows. Et si vous travaillez sur Vista/7, le chemin a plutôt la forme "C:\Users\Hervé\Documents\grenier.html".

Enregistrer une page HTML à partir d'Access

Hervé Inisan — Fri, 23 Apr 2010 15:19:00 +0200

Comment enregistrer sur disque le contenu entier d'une page HTML, à partir d'Access ?

En fait, de VBA en général... Ça marchera donc aussi dans Excel, Word ou toute autre application compatible VBA.

Le principe

Il y a sûrement d'autres moyens de faire, mais dans notre cas, on va sous-traiter le chargement de la page Web par Internet Explorer. On n'aura plus qu'à s'occuper du transfert sur disque...

Ceci continue la série entamée par ces articles :

Le code VBA

Voici une fonction VBA à recopier (comme d'habitude !) dans un module standard de votre base de données :

' ---

' SAUVEGARDE D'UNE PAGE WEB A L'AIDE DE INTERNET EXPLORER

' ---

'

Function EnregistrerHTML( _

  ByVal strURL As String, _

  ByVal strFichier As String) As Boolean

  ' Démarrer et afficher Internet Explorer

  On Error GoTo EnregistrerHTMLErr

  Dim ie As Object

  Set ie = CreateObject("InternetExplorer.Application")

  ie.Visible = True

  ' Naviguer vers l'adresse souhaitée

  ' et attendre qu'elle soit chargée

  ie.navigate strURL

  While ie.Busy

    DoEvents

  Wend

  ' Créer et ouvrir le fichier texte

  Dim intHandle As Integer

  intHandle = FreeFile

  Open strFichier For Output As #intHandle

  ' Ecrire le contenu HTML de la page Web dans le fichier

  Print #intHandle, ie.Document.documentElement.innerHTML

  ' Fermer le fichier et Internet Explorer

  Close #intHandle

  ie.Quit

  ' Renvoyer un code de succès

  EnregistrerHTML = True

  Exit Function

EnregistrerHTMLErr:

  MsgBox "Erreur : " & Err.Description, vbExclamation

  EnregistrerHTML = False

  Exit Function

End Function

Le 1er paramètre de la fonction est l'adresse de la page Web à visiter (et enregistrer).
Le 2ème paramètre est le chemin complet du fichier à créer sur votre disque.
Attention : si le fichier pointé existe, il sera écrasé sans avertissement. Vous pouvez toujours améliorer le code ! :-)
La fonction fournie renvoie True si la sauvegarde de la page Web a pu se faire correctement, et False sinon.

Tester la fonction

Pour tester la fonction rapidement, utilisez la fenêtre Exécution :

Appuyez sur CTRL + G.
Tapez dans la fenêtre Exécution quelque chose comme :
? EnregistrerHTML("http://www.lemonde.fr", "C:\Documents and Settings\Hervé\Mes documents\lemonde.html")
Bien sûr, vous aménagez le chemin du fichier en fonction de votre propre identifiant de session Windows. Et si vous travaillez sur Vista/7, le chemin a plutôt la forme "C:\Users\Hervé\Documents\lemonde.html".

Si ça marche, vous pouvez l'exploiter dans votre application VBA.

Note

La fonction enregistre toute la page HTML, mais pas les documents joints. Donc vous n'enregistrerez pas les images, les feuilles de styles CSS, les fichiers Javascript, etc.

Tuning :-)

La ligne ie.Visible = True permet de voir ce qui se passe, le temps de mettre au point le code. Vous pouvez l'enlever une fois que vous aurez testé...

Ouvrir une page HTML avec mot de passe depuis Access

Hervé Inisan — Mon, 29 Mar 2010 11:59:00 +0200

Dans l'article Piloter Internet Explorer depuis Access, vous avez vu comment ouvrir une page Web en VBA. La technique devient plus intéressante lorsqu'on doit manipuler le code HTML de la page affichée. Dans ce qui suit, nous allons voir comment nous connecter à la section privée d'un site Web, en remplissant automatiquement les identifiant (login) et mot de passe d'un formulaire HTML.

Etape 1 : décrypter le formulaire d'identification

Le formulaire d'identification est la portion de page HTML qui vous demande votre nom (identifiant ou login), et votre mot de passe. Un bouton permet ensuite d'expédier ces informations vers une page ou un script de traitement, qui vérifie si les informations fournies sont correctes. Cette page de traitement est appelée "l'action" en HTML.

Pour atteindre notre objectif, il faut donc connaître :

L'adresse (ou URL) de la page HTML qui contient le formulaire d'identification.
L'action du formulaire, dans la page HTML.
Le nom du champ Identifiant.
Le nom du champ Mot de passe.

Je suppose que vous connaissez l'URL de la page HTML de connexion. Pour obtenir les trois autres informations :

Affichez la page de connexion dans votre navigateur.
Cliquez sur la page du bouton droit, et choisissez Afficher la source (ou Code source de la page, sous Firefox).
Faites un Edition / Rechercher (ou CTRL + F).
Cherchez une portion de HTML qui démarre par <form (en majuscules ou minuscules, ça n'a pas d'importance).
Le formulaire complet est obligatoirement compris entre des balises <form ...> et </form>.
La balise d'ouverture du formulaire s'écrit sous cette forme :
<form action="http://grenier.self-access.com/?post/2010/03/29/xyz.html" method="post">
Notez l'action (ici : xyz.html, mais ça peut être n'importe quoi d'autre !). Vous avez votre première information.
Quelque part entre les balises <form> et </form> doivent se trouver les champs de saisie. Ce sont des balises de la forme :
<input type="..." name="...">
Les 2 champs de saisie qui nous intéressent peuvent par exemple s'écrire :
<input type="text" name="username">
<input type="password" name="password">
Notez les 2 attributs name (ici : username et password). Vous avez vos 2 autres informations !

Attention

Il peut y avoir plusieurs formulaires sur une page Web. Repérez bien sûr le bon !

Etape 2 : le code VBA

On peut maintenant passer à Access...

Ouvrez votre base de données et ajoutez-y un module standard.
Recopiez tout ce qui suit, tel quel, dans le module :

Type AuthFormDef

  ' Adresse à atteindre

  URL As String

  ' Action du formulaire d'identification

  FormAction As String

  ' Nom du champ qui demande le nom d'utilisateur

  UserField As String

  ' Nom du champ qui demande le mot de passe

  PasswordField As String

  ' Valeur du champ Utilisateur

  UserValue As String

  ' Valeur du champ Mot de passe

  PasswordValue As String

End Type

' ---

' CONNEXION A INTERNET EXPLORER AVEC IDENTIFIANT / MOT DE PASSE

' ---

Function ConnexionIE(afd As AuthFormDef) As Boolean

  Dim ie As Object

  Dim doc As MSHTML.HTMLDocument

  Dim frm As MSHTML.HTMLFormElement

  Dim blnFormOK As Boolean

  ' Démarrer et afficher Internet Explorer

  On Error GoTo ConnexionIEErr

  Set ie = CreateObject("InternetExplorer.Application")

  ie.Visible = True

  ' Naviguer vers la page et attendre qu'elle soit chargée

  ie.navigate afd.URL

  While ie.Busy

    DoEvents

  Wend

  ' Récupérer l'objet Document affiché

  Set doc = ie.Document

  ' Identifier le formulaire demandé

  blnFormOK = False

  For Each frm In doc.Forms

    If frm.Action = afd.FormAction Then

      blnFormOK = True

      ' Trouver et renseigner les champs Identifiant/Mot de passe

      ' du formulaire

      Dim obj As Object

      For Each obj In frm.elements

        If obj.Name = afd.UserField Then obj.Value = afd.UserValue

        If obj.Name = afd.PasswordField Then obj.Value = afd.PasswordValue

      Next

      ' Forcer l'envoi du formulaire

      frm.submit

      ConnexionIE = True

    End If

  Next

  ' Valeur de retour

  ConnexionIE = blnFormOK

  Exit Function

ConnexionIEErr:

  MsgBox "Erreur : " & Err.Number & vbCrLf _

    & Err.Description, vbExclamation

  ConnexionIE = False

  Exit Function

End Function

Le programme est composé :

D'un type de données AuthFormDef qui devrait simplifier la description du formulaire et le passage de paramètres.
D'une fonction ConnexionIE qui gère la connexion proprement dite.

Important

Note

Le remplissage des champs du formulaire est moyennement élégant ;-) mais après quelques tests, il semble que l'utilisation d'une variable comme indice du tableau elements pose problème. D'où le hack...

Etape 3 : tester le code

Voici un autre petit programme, que vous ajoutez dans votre module, et qui va permettre de lancer votre connexion proprement dite :

' ---

' TEST DU FORMULAIRE D'IDENTIFICATION

' ---

Sub TestConnexionIE()

  Dim afd As AuthFormDef

  ' Paramètres de la connexion

  With afd

    .URL = "http://www.votre-site.com/formulaire.php"

    .FormAction = "http://www.votre-site.com/identification.php"

    .UserField = "username"

    .PasswordField = "password"

    .UserValue = "votre_identifiant"

    .PasswordValue = "votre_mot_de_passe"

  End With

  ' Lancer la connexion

  If ConnexionIE(afd) Then

    MsgBox "Connexion établie !", vbInformation

  Else

    MsgBox "Echec de la connexion", vbExclamation

  End If

End Sub

Comme vous le voyez, j'utilise la structure AuthFormDef pour renseigner tous les paramètres du formulaire à remplir :

URL
L'adresse (URL) où se trouve le formulaire sur le Web.
FormAction
L'action du formulaire, que vous avez repérée plus tôt, et qui permet de trouver le formulaire dans la page Web.
UserField
Le nom du champ Identifiant.
PasswordField
Le nom du champ Mot de passe.
UserValue
La valeur du champ Identifiant (votre identifiant à vous !)
PasswordValue
La valeur du champ Mot de passe (votre mot de passe !).

Il ne reste plus qu'à appeler la fonction ConnexionIE, en lui transmettant la structure. Cette fonction renvoie True si la connexion s'est bien passée, et False sinon.

Attention

Le programme peut ne pas marcher sur tous les formulaires d'identification. Tout dépend de la façon dont ils sont traités et validés.

Piloter Internet Explorer depuis Access, par Automation

Hervé Inisan — Sun, 28 Mar 2010 16:07:00 +0200

Comment piloter Internet Explorer à partir d'Access, en utilisant Automation ?

Petit rappel

Avant de lancer des usines à gaz :-), je vous rappelle qu'il est possible d'ouvrir un lien hypertexte (en démarrant automatiquement votre navigateur par défaut), à l'aide de l'instruction DoCmd.FollowHyperlink.

Maintenant, si vous souhaitez piloter Internet Explorer de façon plus précise, vous aurez besoin de ce qui suit. La technique permet entre autres de manipuler le contenu de la page HTML affichée, nous le verrons dans un prochain article.

Exemple simple

Dans cet article, on va démarrer simplement... :-) Voyons comment démarrer Internet Explorer et afficher une page HTML dont on connaît l'adresse (l'URL). En gros, comment reproduire exactement le comportement de FollowHyperlink, mais en plus complexe !

Recopiez ce code dans un module standard de votre base de données :

' ---

' PILOTAGE SIMPLE DE INTERNET EXPLORER

' ---

'

Sub NaviguerVers(ByVal strURL As String)

  Dim ie As Object

  ' Démarrer et afficher Internet Explorer

  Set ie = CreateObject("InternetExplorer.Application")

  ie.Visible = True

  ' Naviguer vers l'adresse souhaitée

  ie.navigate strURL

End Sub

Le programme crée une instance de Internet Explorer à l'aide de la fonction CreateObject().
Le Visible = True garantit que le navigateur s'affiche à l'écran. Sans cela, il est démarré mais pas affiché, vous le voyez seulement dans la liste des tâches de Windows : [Ctrl] + [Alt] + [Suppr].
Enfin, la méthode Navigate permet de... naviguer vers l'adresse souhaitée.

Tester !

Pour appeler la procédure ci-dessus, vous écrirez par exemple :

NaviguerVers "http://www.self-access.com"

Vous pouvez tester dans la fenêtre Exécution (CTRL + G), et bien sûr utiliser cette instruction dans n'importe quel bloc Sub / End Sub ou Function / End Function de votre base de données.